翻译下ansys命令流

这是我翻译的，感觉对了就说声，呵呵

/RGB,INDEX,100,100,100, 0 ! 下面四个是对画布的颜色设置，可以看出变为白色

/RGB,INDEX, 80, 80, 80,13

/RGB,INDEX, 60, 60, 60,14

/RGB,INDEX, 0, 0, 0,15

/REPLOT ! 自动重新发布上一个显示命令，也有重绘之意

/filename,test2-s ! 更改文件名字为test2-s.db

/title,thermal analysis in TiAl alloy ! 文件标题

/prep7 ! 预处理，及定义几个变量

X0=0.015

Y0=0.001

Y1=0.00003

Y2=0.00003

KXX1=15.1

C1=492

DENS1=3760

KXX2=15.44

C2=1088.3

DENS2=3990

KXX3=2.09

C3=456.7

DENS3=4760

TEMP1=20

TEMP2=800

TIM1=15

ET,1,PLANE55 ! 选用2维热实体平面单元

KEYOPT,1,3,1 ! 定义板为轴对称，这是定义单元的关键选项，与55单元是对应的

MP,KXX,1,KXX1 ! 定义导热系数，值为KXX1

MP,C,1,C1 ! 比热

MP,DENS,1,DENS1 ! 密度

MP,KXX,2,KXX2 ! 第二组，上同

MP,C,2,C2

MP,DENS,2,DENS2

MP,KXX,3,KXX3

MP,C,3,C3

MP,DENS,3,DENS3

RECTNG,0,X0,0,Y0 ! 建立模型，为矩形，三个

RECTNG,0,X0,Y0,Y0+Y1

RECTNG,0,X0,Y0+Y1,Y0+Y1+Y2

aglue,all ! 把上面三个面胶成一个面

NUMCMP,ALL ! 压缩定义的条款，项目

/REPLOT

/PNUM,LINE,1 ! 为线显示编号

/REPLOT

LSEL,S,,,1,3,2 ! 重新选择一组线，从1到3，间隔是2，所以只选则了1和3面；

LSEL,A,,,5,6 ! 在选择面5和6

LESIZE,ALL,,,80 ! 选择的所有的线分成80份

LSEL,S,,,2,4,2 ! 在重新选择线2、4

LESIZE,ALL,,,20

LSEL,S,,,7,10

LESIZE,ALL,,,1

ASEL,,,,1 ! 选择面，1号

AATT,1,,1,0 ! 为没有网格的面选择网格属性，这里的材料属性为第一组材料属性

ASEL,,,,2

AATT,2,,1,0

ASEL,,,,3

AATT,3,,1,0

ALLSEL,ALL ! 选择全部的线面等

AMESH,ALL ! 对面进行网格划分；

/TITLE,ELEMENTS IN MODEL ! 标题

EPLOT ! 显示单元

FINISH

/SOLU ! 求解命令流

TUNIF,TEMP1 ! 为结点施加统一的温度：temp1

TIME,TIM1 ! 定义载荷的施加时间为：tim1

DELTIM,1,1,4 ! 定义载荷步，以及范围

AUTOTS,ON ! 使用自动载荷步

OUTRES,,ALL ! 输出所有信息

LSEL,S,,,6 ! 选择线6

NSLL,S,1 ! 选择已经选择好的线上的结点，所有的包括内部的联合的结点

D,ALL,TEMP,TEMP2 ! 所有结点施加温度约束temp2

ALLSEL,all ! 选择所有信息

SOLVE ! 求解

FINISH ! 从处理器中退出来

/PREP7

*SET,ALPX1,13.5e-6 ! 定义变量的有一种方式

*SET,ALPX2,8.5e-6

*SET,ALPX3,9e-6

*SET,EX1,135.78

*SET,EX2,372

*SET,EX3,166

*SET,PRXY1,0.214

*SET,PRXY2,0.3

*SET,PRXY3,0.3

ETCHG,TTS ! 转变单元类型，可以变为PLANE182单元，为结构单元

KEYOPT,1,3,1 ! 也是轴对称图形

MP,ALPX,1,ALPX1 ! 属性，热膨胀正交系数

MP,EX,1,EX1 ! 弹性模量

MP,PRXY,1,PRXY1 ! 大的波松比；；；；；下面几个类似，不过是第二组和第三组的材料属性

MP,ALPX,2,ALPX2

MP,EX,2,EX2

MP,PRXY,2,PRXY2

MP,ALPX,3,ALPX3

MP,EX,3,EX3

MP,PRXY,3,PRXY3

TREF,20 ! 热膨胀参考温度

NSEL,S,LOC,X,0 ! 选择X=0，就是YOZ皮昂面的结点

D,ALL,UX ! 对选择的结点进行X方向位移约束

NSEL,,,,1 ! 选择1号结点

D,ALL,,,,,,ALL ! 所有反向进行约束

ALLSEL,ALL

FINISH

/SOLU

ANTYPE,STATIC ! 静力分析

ldread,temp,,,,,test2-s,rth ! 从结果文件中读入文件作为载荷

ALLSEL

solve

FINISH

/post1 ! 后处理，常规的

/PLOPTS,INFO,ON ! 显示图列等信息选项打开

PLNSOL,S,EQV ! 显示换算应力

Finish